Category Archives: AppleScript

Mac workflow: Alfred set color label

Leave a reply

A probléma Egér nélkül akarjuk a Finderben kiválasztott elemek color label tag-jét beállítani.

A megoldás

Csinálunk hozzá Alfred workflow-t. A workflow kétféleképpen használható:

Van benne 8, paraméter nélkül használható keyword: lred, lorange, lyellow, lpurple, lblue, lgreen, lgray, lnone – ezek értelemszerűen a nevekben szereplő színűre állítják a kiválasztott Finder elemeket.
Az “scl” kulcsszóval és az utána írt color paraméterrel ugyanígy beállítja a kívánt színt a Finder által használt 7 féle variációból:

A workflowt szedheted a packal.org-ról, vagy tőlem innen. ]]>

Mac workflow: textfile to Reminders items

Leave a reply

Tatra panorama Erától kaptam szép hosszú ~~szerelmetes levelet~~ to-do listát emailben, amit nekem kényelmesebb lenne kipipálgatni egy Reminders listában. Szerencsére van egy kis eszünk, AppleScriptünk, meg a Remindersnek AppleScript supportja, úgyhogy csak bemásoljuk az emailből a hosszú listát a clipboardba, aztán ráeresztjük ezt a scriptet és voila:

tell application "System Events"
	set myText to paragraphs of (the clipboard as text)
end tell
repeat with myLine in myText
	if length of myLine is greater than 0 then
		tell application "Reminders"
			tell list q
				make new reminder with properties {name:myLine}
			end tell
		end tell
	end if
end repeat

]]>

Mac workflow: klikkmentes to do

Leave a reply

Things alkalmazást. Ez egész odáig tartott, míg a fejlesztő srácok el nem kezdték ígérgetni a cloud sync támogatást, ami csak nem akart megérkezni – én pedig továbbléptem, előbb a The Hit List-re, aztán az OS X / iOS gyári Reminders alkalmazására, majd a német Wunderlist appra. Mindegyikkel volt valami bajom, aztán nemrég szembejött egy review, amiben újra nyakig dícsérték a Things-et, ezért úgy gondoltam, visszanézek – és nem bántam meg 🙂 Amivel már jó ideje kísérletezek az az, hogy a munka közben eszembe jutó teendőket minél kevesebb erőfeszítéssel rögzíthessem. Erre optimális lenne, ha a feladatkezelő alkalmazás korrektül scriptelhető lenne, én meg egy Alfred workflow-val beletolhatnám a mondandómat – ezt fogjuk most megcsinálni a Things mellé. A Things-hez létezik már többféle Alfred workflow, én viszont egyikkel sem voltam elégedett. Olyat szerettem volna, amihez egy sorban kitölthetem a taskhoz tartozó összes paramétert mindenféle egerezés nélkül. Ehhez még hozzáálmodtam azt is, hogy felszedhetné az aktív Safari ablak URL-jét és az oldal címét, hátha csak épp azt akarom elmenteni. Tudom, van Reading list Safariban, amit viszont nem tudok taggelni és főleg fejlesztői doksiknál sokszor élem át azt, hogy emiatt nem találok meg egy korábban látott oldalt. Szóval legyen benne task description meg task note kitaláló, de gyorsan állíthassak határidőt, feladatcsoportot és tageket is. Kitaláltam ehhez a következő szintaxist: Az eleje a feladat leírása, a @ után álló “3d print” a feladatcsoport (a Things nyelvén “project vagy area of responsibility”), a # utáni “Ultimaker” a feladatra akasztott címke, a > karaktert követő 1 érték pedig azt mondja a workflownak, hogy ez a munka holnap határidős. Mindezt látod is on-the-fly, ahogy gépeled be a feladatot. Csak elsőre hangzik bonyolultan, 5 task kézzel és már ott is van az izommemóriában 🙂 Ez pedig a Safari autofill – így néz ki, amikor felszedi az aktív Safari ablak címét és URL-jét: A > karakter utáni dátummal tud minimálisat matekozni. Megadhatsz neki 8 (=YYYYMMDD), 6 (=YYMMDD), 4 (=MMDD), vagy 2 (=DD) jegyű dátumot – ha nem teljes a dátum, akkor a hiányzó darabokat az aktuális napi dátumból kiegészíti. Magyarul a >1201 ma 2014 december elsejét jelenti a workflownak. Ezen túlmenően tud hozzáadni illetve elvenni napokat az aktuális dátumból: az első karakter az előjel, azt követi egy szám, majd az utolsó karakter opcionálisan jelölhet nap helyett hetet (w), hónapot (m) vagy évet (y). Egy példán keresztül: a mai napon gyártott to do-n a >+3w dátummatek 2014 december 17-ét állítja be due date-nek, mivel az van 3 hét múlva. Ha tetszik és kipróbálnád, a workflow-t szedheted tőlem vagy a packal.org-ról is. Update: kicsit szellősebbre vettem a parser által kitalált to do elemeket, illetve most már felismeri a @today és @someday targeteket is és a megfelelő Things listákba pakolja az így címzett to do itemeket: ]]>

Mac workflow: Alfred

Leave a reply

Alfred viszont annál inkább a szívemhez nőtt. Az Alfred a készítők definíciója szerint egy “productivity” alkalmazás, mely a korábbi Quicksilver, illetve a most is aktívan fejlesztett Launchbar launcherek konkurrense. Most eltekintek attól, hogy a sok default Alfred jóságot részletesen ismertessem, azokról született már kismillió jó írás. Rettenet erő lakik a szoftverben, főleg, ha pénzt áldozol a 17 GBP-be kerülő PowerPack kiegészítésre. Amint van PowerPackod, már gyárthatod is a friss workflow-kat Alfredben. Én is csináltam sok ilyet és használok mások által fejlesztetteket – ebből szedtem most össze egy csokorra valót kedvcsinálónak. Lássuk a macit!

Uni-Call

FaceTime vagy Skype hívást tudok desktopról indítani anélkül, hogy az egeret használnám, így:

Currency converter

Árfolyamot vált, baromi gyorsan, bármiről bármire. Beállíthatod a kedvenc célárfolyamod default targetnek, de harmadik paraméterként bármikor konvertálhatsz tetszőleges másikra is:

Image dimensions

Kép méretét adja vissza azonnal:

Encode

URL/UTF8/Base64 formába konvertálja az inputot:

Animgif search

Google translate

UI-ben tökölés nélkül fordítja az inputot azonnal. Csináltam belőle 3 targetet: magyarra, angolra és lengyelre:

Safari history search

IP és Mac addressek CLI nélkül, gyorsan

Disk space check azonnal

Compose mail

Keresés a menubarban egér nélkül

Új file gyártása és azonnali megnyitása

Cheatsheet azonnal

Rate current iTunes track és add current iTunes track to singalong playlist

Recent items

Save current URL with tags

Send current URL

Show all iCloud tabs

Timezones

Ha kedvet csináltam, már megérte! ]]>

Mac workflow: Tagged bookmarks

Leave a reply

OpenMeta tagging felfedezése óta használom OS X alatt a tageket (btw OpenMeta tagek: OS X 10.9 alatt bevezetett kMDItemOMUserTags tagekké konvertálására itt ez a csodás script). A 10.9 megjelenése óta várom, hogy majd csak belekerül a Safari bookmarkok mellé is a tagging lehetősége – aztán egy nap meguntam a várakozást és csináltam magamnak egy scriptet a probléma megoldására:

set defaultPath to "SYSTEM:Users:fns:Dropbox:URL" as alias
tell application "Safari"
	set theName to name of front document
	set theURL to URL of front document
end tell
set theName to replace_chars(theName, ":", " -")
tell application "Safari"
	activate
	set resultFile to (choose file name with prompt "Save .webloc File" default name theName default location defaultPath) as text
end tell
set text item delimiters to ":"
set fileName to last text item of resultFile
set filePath to text 1 thru lastpos(resultFile, ":") of resultFile
tell application "Finder" to make new internet location file at filePath to theURL with properties {name:fileName}
on replace_chars(this_text, search_string, replacement_string)
	set AppleScript's text item delimiters to the search_string
	set the item_list to every text item of this_text
	set AppleScript's text item delimiters to the replacement_string
	set this_text to the item_list as string
	set AppleScript's text item delimiters to ""
	return this_text
end replace_chars
on lastpos(textstring, thischar)
	return (length of textstring) - (offset of thischar in (reverse of text items of textstring as string))
end lastpos

Ha elindítod a scriptet, akkor az feldob egy file save requestert, amiben átírhatod a mentendő .webloc file nevét, illetve tageket definiálhatsz. Nálam az így mentett .webloc file-ok a Dropboxban tartott URL nevű folderbe kerülnek, így minden gépemre szépen szinkronizálódnak, metadatával együtt. A default mentési foldert ebben a sorban definiálhatod át:

set defaultPath to "SYSTEM:Users:fns:Dropbox:URL" as alias

A scriptet nálam egy Alfred workflow indítja, de futtathatod akár egy FastScripts keyboard shortcuttal, csinálhatsz belőle Automator service-et, vagy ahogy neked kényelmes – TIMTOWTD.]]>

Mac workflow: screenshot megosztás

Leave a reply

Józsinál olvastam az előbb, hogy szerinte az optimális megoldás screenshot megosztásra, ha bekapcsolja a Dropbox automata képernyőfotó uploaderét, ami majd feltölt minden screenshotot a cloudba. Én ettől kifejezetten viszolygok, viszont egészen hasonló, csak picit paranoidabban kontrollált megoldást használok ugyanerre. Józsi nem szereti a 3rd party szoftvereket, így neki ez a verzió valószínűleg nem játszik, de ha te is hozzám hasonló shareware junkie vagy, akkor neked még jól jöhet az én workflow-m. Megosztásra én is a Dropboxot használom, csak épp nem hagyom neki, hogy hübele-Balázs mindent feltöltsön a felhőbe. Ehelyett létrehoztam a Dropbox folderben egy screenshots mappát, ami droptargetként kint van a dokkon és abba dobom a megosztandó screenshotot. A folderen ül egy Hazel folder rule, ami a beérkező file nevéből kitalálja, hogy mi lesz a Dropbox URL, majd azt bepakolja a Clipboardra:

set file_path to theFile as text
try
	set text item delimiters to ":"
	set file_name to last text item of file_path
	set text item delimiters to ""
on error
	set text item delimiters to ""
end try
set file_name to (do shell script "/usr/bin/php -r 'echo rawurlencode(\"" & file_name & "\");'")
set dropboxPath to "https://dl.dropboxusercontent.com/u/MYDROPBOXID/screenshots/" & file_name
set the clipboard to dropboxPath

A scriptben szereplő MYDROPBOXID szöveget a saját Dropbox ID-dre kell cserélni, hogy működjön a dolog. Ehhez elég, ha egyetlen, a Dropbox felhőben levő file URL-jét meglesed, ott van benne az ID. Én ezen túl még “kettőre zárom” a dolgot: futás után megváltoztatom a file color ~~labelét~~ tagjét szürkére:

A módszer egyetlen hátránya, hogy sokszor a Hazel rule előbb készül el a clipboardba rakott URL-lel, mint ahogy a file felérne a felhőbe, így ha gyorsan osztod meg a linket, akkor előfordulhat, hogy az még nem él. Ha a Dropbox folderében levő file-okról meg lehetne tudni valahogy, hogy azok felkerültek-e már a felhőbe, akkor ez a probléma is megoldódna. Mielőtt bárki “de hát van stock Folder Acctions!”-t kiáltana, fűszerezzük meg még egy Hazel szépséggel: ha kidobnád, vagy csak archiválnád a screenshotjaidat, mert mondjuk zavar, hogy foglalja a Dropbox tárhelyed, akkor archiváltasd őket automatikusan:

Ugyanezt persze meg lehetne csinálni saját tárhelyre FTP-zve is – akkor még a feltöltés-linkgyártás combo sem csúszna meg. Aki megírná ehhez a scriptet, nosza itt a comment box!-)

Update

Csak azért, hogy kiálljak a szerintem egyik leghasznosabb OS X alkalmazás mellett, olvastam Hazel doksit és megcsináltam az egészet Dropbox nélkül is. Ehhez mindössze egy FTP tárhelyre van szükséged – íme a rule:

A fenti scripthez képest természetesen csak a https://dl.dropboxusercontent.com/u/MYDROPBOXID/screenshots/ értékét kell arra a folderre változtatnod, ahova feltöltetted a képet.]]>

clipboardToReminders

Leave a reply

set rLists to {}
tell application "Reminders"
	set todo_accounts to every account
	repeat with i from 1 to length of todo_accounts
		set todo_lists to get every list
		repeat with j from 1 to length of todo_lists
			tell list j
				set end of rLists to (get name)
			end tell
		end repeat
	end repeat
end tell
set myRList to choose from list rLists with title "Save these clipboard as Reminder(s)" with prompt (get the clipboard) without multiple selections allowed
if myRList is not false then
	tell application "System Events"
		set myText to paragraphs of (the clipboard as text)
	end tell
	repeat with myLine in myText
		if length of myLine is greater than 0 then
			tell application "Reminders"
				tell list (item 1 in myRList)
					make new reminder with properties {name:myLine}
				end tell
			end tell
		end if
	end repeat
end if

]]>

Mac workflow: Open source URL, v2

Leave a reply

A probléma Leszedtél egy file-t valahonnan, a browser beletette a file metaadatai közé, hogy honnan kotortad azt elő a neten és most vissza kellene találnod a forráshoz.

A megoldás

Korábban ezt megcsináltuk Thingiverse-specifikusra, de nem tetszett, hogy a script önkényesen dönt, hogy nekem épp melyik URL kell, ezért faragtam belőle popup menüset, amivel Te választhatsz, hogy melyik metában tárolt URL-t nyissa a Safari. Lustáknak itt a bezippelt workflow, aki meg olvasgatná itt a postban a forrást az ide nézzen:

on run {input, parameters}
	set theFile to (input)
	set aFile to quoted form of POSIX path of theFile
	set theURL to (do shell script "mdls -name kMDItemWhereFroms -raw " & aFile)
	if theURL is "(null)" then -- no attribute
		set theURL to "(URL info not found)"
		set theMessage to ""
	else
		set URLs to {}
		repeat with i from 1 to the count of paragraphs of theURL
			set p to paragraph i of the theURL
			set firstQ to findFirst(p, "\"")
			set lastQ to lastOffset(p, "\"")
			if firstQ > 0 and lastQ > 0 and (lastQ - firstQ > 1) then
				copy characters (firstQ + 1) through (lastQ - 1) of p as string to q
				set end of URLs to q
			end if
		end repeat
		set selectedURL to false
		if (count of URLs) = 1 then
			set selectedURL to (item 1 of URLs)
		else if (count of URLs) > 1 then
			set selectedURL to (choose from list URLs with title "Open URL" with prompt "Select URL to open:" without multiple selections allowed)
		end if
		if (selectedURL is not false) then
			tell application "Safari"
				tell window 1
					set current tab to (make new tab with properties {URL:selectedURL as text})
				end tell
			end tell
		end if
	end if
	return input
end run
on findFirst(str, findString)
	-- HAS (http://applemods.sourceforge.net/mods/Data/String.php)
	local str, findString, len, oldTIDs
	set oldTIDs to AppleScript's text item delimiters
	try
		set str to str as string
		set AppleScript's text item delimiters to findString
		considering case
			set len to str's first text item's length
		end considering
		set AppleScript's text item delimiters to oldTIDs
		if len is str's length then
			return 0
		else
			return len + 1
		end if
	on error eMsg number eNum
		set AppleScript's text item delimiters to oldTIDs
		error "Can't findFirst: " & eMsg number eNum
	end try
end findFirst
on lastOffset(the_text, char)
	try
		set i to 1
		set last_occurrence to 0
		repeat count of the_text times
			if item i of the_text as string = char then
				set last_occurrence to i
			end if
			set i to i + 1
		end repeat
	on error
		return 0
	end try
	return last_occurrence
end lastOffset

]]>

Mac workflow: Open source URL service

1 Reply

erre. Ahogy töltögettem le Karácsony előtt a sok printelni való STL file-t a Thingiverse-ről, egyre többször jött elő, hogy meg kellene újra néznem valamit az STL file-t tartalmazó oldalon újra. Szerencsére OS X alatt a kMDItemWhereFroms metadata attribútumba bekerül a letöltés URL-je, amit én néha meg-meg néztem már korábban is egy vérbuta shell scripttel, ami nálam eddig így nézett ki:

#!/bin/sh
mdls -name kMDItemWhereFroms -raw "$*"

Ez egy zárójelek közé zárt comma delimited URL listát ad vissza. Nekem ebből az URL listából az utolsó kellene (a Thingiverse Amazon S3 storage-et használ, az első URL a storage-ra mutat, míg a második az eredeti Thingiverse oldalra), mégpedig minél kevesebb szüttyögéssel, azaz monjduk egy Service formájában. Némi rövid googling után dobta a gép a közel konyhakész scriptet a MacScripter oldaláról, már csak hozzá kellett ragasztani az Automator Service script számára szükséges paraméterátvételt és kész is:

property getSpecific : false -- show the specific download URL?
on run {input, parameters}
	set theFile to (input)
	set aFile to quoted form of POSIX path of theFile
	set theURL to (do shell script "mdls -name kMDItemWhereFroms -raw " & aFile)
	if theURL is "(null)" then -- no attribute
		set theURL to "(URL info not found)"
		set theMessage to ""
	else
		if getSpecific then -- get the first item (the download URL)
			set theURL to paragraph 2 of theURL
			set here to offset of "\"" in theURL
			set theURL to text (here + 1) thru -3 of theURL -- the download URL
			tell application "Finder"
				set name of theFile to theURL --I have no idea what im doing
			end tell
		else -- get the last item (the page/site URL)
			set theMessage to "page/site "
			set theURL to paragraph -2 of theURL
			set here to offset of "\"" in theURL
			set theURL to text (here + 1) thru -2 of theURL
		end if
		tell application "Safari"
			tell window 1
				set current tab to (make new tab with properties {URL:theURL})
			end tell
		end tell
	end if
	return input
end run

Ebből nagyjából két klikk az Automator workflow megalkotása, de ha ezzel bajban lennél, akkor

konyhakész service zippelt változata leszed innen
bemásol a ~/Library/Services/ folderbe, majd ott kicsomagol

]]>

Yet another meteo script update

Leave a reply

korábbi időjárásscript aktualizált verziója, régi és friss Growl-ra, fixált curl hívással:

(*
	Meteo
	by Gabor PENOFF (//fns.pappito.com)
	release 20111215_161716
	Requirements:
	- before run you need to Enable Access for Assistive Devices in SysPrefs/Universal Access
	- install Growl to get non-modal notification dialogs
	Usage:
	- just run the script
	That's all.
*)
set myScriptID to "Meteo" -- ID for Growl display
-- set date variables:
set myYear to get text 1 thru 4 of (year of (current date) as string)
set myMonth to month of (current date) as number
if myMonth < 10 then set myMonth to "0" & myMonth as string
set myDay to day of (current date)
if myDay < 10 then set myDay to "0" & myDay as string
set myHour to hours of (current date)
if myHour < 10 then set myHour to "0" & myHour as string
set myMinute to "00"
set tmpDir to "delme-meteo"
set myFilePrefix to "delme-met-"
set tIdokepStart to "http://www.idokep.hu/arch_kep.php?kep="
set myURLs to {¬
	"http://terkep.idokep.hu/kep.php?kep=mix|jpg", ¬
	"http://terkep.idokep.hu/kep.php?kep=hoterkep2&regio=hu1680|jpg", ¬
	"http://terkep.idokep.hu/kep.php?kep=felhokep2&regio=hu1680|jpg", ¬
	"http://terkep.idokep.hu/kep.php?kep=szelterkep2_anim|gif", ¬
	"http://terkep.idokep.hu/kep.php?kep=szelterkep2&regio=hu1680|jpg", ¬
	"http://terkep.idokep.hu/kep.php?kep=legnyomasterkep|jpg", ¬
	"http://feny.idokep.hu/kep.php?kep=csap24|jpg", ¬
	"http://feny.idokep.hu/kep.php?kep=csap1|jpg", ¬
	"http://feny.idokep.hu/kep.php?kep=aqua|jpg", ¬
	"http://terkep.idokep.hu/kep.php?kep=rh|jpg", ¬
	"http://terkep.idokep.hu/kep.php?kep=uv|jpg", ¬
	"http://terkep.idokep.hu/kep.php?kep=pollen0|jpg", ¬
	"http://terkep.idokep.hu/kep.php?kep=radar&regio=eu|jpg"}
set rootDir to (path to home folder as string) & "Pictures"
tell application "Finder" to set fullDir to rootDir & ":" & tmpDir -- save fullDir
set myNotification to "Downloading METEO images to " & (POSIX path of fullDir) & "..."
tell me to notifyWithGrowl(myScriptID, myNotification)
try
	tell application "Finder" to delete fullDir
end try
tell application "Finder" to make new folder at alias rootDir with properties {name:tmpDir}
-- download files:
--tell application "URL Access Scripting.app"
set i to 1
repeat with myURL in myURLs
	set thisURL to (text 1 thru ((offset of "|" in myURL) - 1) of myURL)
	set thisExt to (text ((offset of "|" in myURL) + 1) thru (length of myURL) of myURL)
	set the myFile to fullDir & ":" & myFilePrefix & i & "." & thisExt
	--set myFile to ((path to temporary items) as string) & "url_access_file.xml"
	--«event aevtdwnl» thisURL given «class fdst»:file myFile, «class rplc»:«constant erplyes »
	do shell script "curl -L \"" & thisURL & "\" -o \"" & (POSIX path of myFile) & "\""
	set i to i + 1
end repeat
--end tell
-- display images using full-featured QuickLook window:
tell application "Finder"
	activate
	open folder fullDir
	set current view of front Finder window to list view
end tell
tell application "System Events"
	key code 0 using {command down} -- cmd+a
	key code 49 using {option down} -- cmd+opt+y; y is 16 for US, 6 for Hungarians :)
end tell
-- that would be the callback after QuickLook:
--tell application "Finder"
--	activate
--	set current view of front Finder window to v
--	close front Finder window
--end tell
-- display images using a very limited (dumb) QuickLook window:
--do shell script "qlmanage -p  " & (POSIX path of fullDir) & "/* >& /dev/null"
-- GrowlCheck:
on growlInstalled()
	try
		do shell script "ls /Library/PreferencePanes/Growl.prefPane/"
		return true
	on error
		try
			do shell script "ls -d /Applications/Growl.app"
			return true
		on error
			return false
		end try
	end try
end growlInstalled
-- Growl notifier:
on notifyWithGrowl(myApp, myText)
	set myIconApp to "SYSTEM:Users:fns:Documents:Scripts:meteo"
	set notificationID to myApp & ".default"
	if growlInstalled() then
		tell application "Growl"
			-- list of notification types
			set the ANL to {notificationID}
			-- list of enabled notifications
			set the DNL to {notificationID}
			-- register script
			register as application myApp all notifications ANL default notifications DNL icon of application myIconApp
			-- send notification
			notify with name notificationID title myApp description myText application name myApp
		end tell
	else
		-- skip alert if no Growl installed
		--display alert "Growl is not installed"
	end if
end notifyWithGrowl

Lustáknak zip-be csomagolt, script app-ba fordított, szuperszexi trn weather ikonos verzió leech erre.]]>

eFi.blog

szánSájn, tibiCsoki, wörldPísz!

Category Archives: AppleScript

Mac workflow: Alfred set color label

A megoldás

Mac workflow: textfile to Reminders items

Mac workflow: klikkmentes to do

Mac workflow: Alfred

Uni-Call

Currency converter

Image dimensions

Encode

Animgif search

Google translate

Safari history search

IP és Mac addressek CLI nélkül, gyorsan

Disk space check azonnal

Compose mail

Keresés a menubarban egér nélkül

Új file gyártása és azonnali megnyitása

Cheatsheet azonnal

Rate current iTunes track és add current iTunes track to singalong playlist

Recent items

Save current URL with tags

Send current URL

Show all iCloud tabs

Timezones

Mac workflow: Tagged bookmarks

Mac workflow: screenshot megosztás

Update

clipboardToReminders

Mac workflow: Open source URL, v2

A megoldás

Mac workflow: Open source URL service

Yet another meteo script update